Начало блога » 2018 » Январь » 19 » Возможности Excel
04:35

Возможности Excel

Удалить слова справа и добавить символ

Итак, у вас имеется, например имена с фамилиями.
Задача: удалить все что справа и добавить что-то свое

  1. В ячейку "B1" запишите формулу
    =ЛЕВСИМВ(A1;НАЙТИ("*";ПОДСТАВИТЬ(A1;" ";"*";1)))
    и нажмите Ввод и заполнить ВНИЗ
  2. Выделите все что в столбце "B" и скопируйте значения вставьте в столбец "C"
  3. В ячейку "D1" для удаления пробелов пишите формулу
    =СЖПРОБЕЛЫ(C1)
    и нажмите Ввод и заполнить ВНИЗ
  4. В столбик "E" вставьте значения из "D"
  5. В ячейку "F1" пишите формулу для добавления значения  |
    в любом случае, ваше значение заключается в кавычки
    =E1&" |"
    и нажмите Ввод и заполнить ВНИЗ

Как выполнить заполнение быстро?

Видите маленький квадратик в правом нижнем углу, как на картинке?
Хватаете его мышкой(появится крестик) и тянете вниз до последней нужной ячейки.

Удалить слова справа

Как извлечь слова из строки таблицы Excel

Формулы в этой статье полезны для извлечения слов из текста, содержащегося в ячейке. Например, вы можете создать формулу для извлечения первого слова в предложении.

Извлечение первого слова из строки

Для извлечения первого слова из строки, формула должна найти позицию первого символа пробела, а затем использовать эту информацию в качестве аргумента для функции ЛЕВСИМВ. Следующая формула делает это:

=ЛЕВСИМВ(A1;НАЙТИ(" ";A1)-1)

Эта формула возвращает весь текст до первого пробела в ячейке A1. Однако у нее есть небольшой недостаток: она возвращает ошибку, если текст в ячейке А1 не содержит пробелов, потому что состоит из одного слова. Несколько более сложная формула решает проблему с помощью новой функции ЕСЛИОШИБКА, отображая все содержимое ячейки, если произошла ошибка:

=ЕСЛИОШИБКА(ЛЕВСИМВ(A1;НАЙТИ(" ";A1)-1);A1)

Если вам нужно, чтобы формула была совместима с более ранними версиями Excel, вы не можете использовать ЕСЛИОШИБКА. В таком случае придется обойтись функцией ЕСЛИ и функцией ЕОШ для проверки на ошибку:

=ЕСЛИ(ЕОШ(НАЙТИ(" ";A1));A1;ЛЕВСИМВ(A1;НАЙТИ(" ";A1)-1))

еще один пример:

Excel - Удалить слова справа и оставить одно

=ЛЕВСИМВ(A1;НАЙТИ("*";ПОДСТАВИТЬ(A1;" ";"*";1)))

нажмите Ввод и заполнить ВНИЗ

Извлечение последнего слова строки

Извлечение последнего слова строки — более сложная задача, поскольку функция НАЙТИ работает только слева направо. Таким образом, проблема состоит в поиске последнего символа пробела. Следующая формула, однако, решает эту проблему. Она возвращает последнее слово строки (весь текст, следующий за последним символом пробела):

=ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ("*";ПОДСТАВИТЬ(A1;" ";"*";ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;" ";"")))))

Но у этой формулы есть такой же недостаток, как и у первой формулы из предыдущего раздела: она вернет ошибку, если строка не содержит по крайней мере один пробел. Решение заключается в использовании функции ЕСЛИОШИБКА и возврате всего содержимого ячейки А1, если возникает ошибка:

=ЕСЛИОШИБКА(ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ("*";ПОДСТАВИТЬ(A1;" ";"*";ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;" ";"")))));A1)

Следующая формула совместима со всеми версиями Excel:

=ЕСЛИ(ЕОШ(НАЙТИ(" ";A1));A1;ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ("*";ПОДСТАВИТЬ(A1;" ";"*";ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;" ";""))))))

Извлечение всего, кроме первого слова строки

Следующая формула возвращает содержимое ячейки А1, за исключением первого слова:

=ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ(" ";A1;1))

Если ячейка А1 содержит текст 2008 Operating Budget, то формула вернет Operating Budget.

Формула возвращает ошибку, если ячейка содержит только одно слово. Следующая версия формулы использует функцию ЕСЛИОШИБКА, чтобы можно было избежать ошибки; формула возвращает пустую строку, если ячейка не содержит более одного слова:

=ЕСЛИОШИБКА(ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ(" ";A1;1));"")

А эта версия совместима со всеми версиями Excel:

=ЕСЛИ(ЕОШ(НАЙТИ(" ";A1));" ";ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ(" ";A1;1)))
Категория: Офисные | Просмотров: 114 | Добавил: masterov | Теги: компьютерная помощь, Windows, Excel | Рейтинг: 0.0/0
Всего комментариев: 0
avatar